Оформление и рефакторинг сложных логических выражений

Программирование - Практика программирования

В сложных логических выражениях нередко самому автору спустя какое-то время тяжело разобраться, не говоря уже о других программистах. Предлагаемая методика позволяет повысить наглядность таких выражений путем оформления в виде И-ИЛИ дерева и одновременно выполнять их рефакторинг.

Возьмем для примера фрагмент кода из типовой бухгалтерии

Если ((НомерИзменяемойКолонки = "4") Или (НомерИзменяемойКолонки = "5"))
Или (((НомерИзменяемойКолонки = "7") Или (НомерИзменяемойКолонки = "8")
И (ГруппаРасчета = мИдГруппы7))) Тогда
    Расчет(ГруппаРасчета);
КонецЕсли;

Не правда ли от количества скобок "рябит в глазах"? Конечно скобки иногда необходимы для расстановки последовательности вычисления, но записывая их линейно в таком количестве мы заметно усложняем восприятие (читаемость) выражения.

Приоритеты логических операций

Для начала вспомним приоритеты логических операций. Сначала выполняется Не, потом И и затем Или. Скобки традиционно имеют наивысший приоритет выполнения и гарантируют порядок выполнения вложенных в них операций. Однако их избыточное применение создает продемонстрированные в примере трудности. Зачастую скобки ставят лишь для того, чтобы перестраховаться в сложных и плохо читаемых логических выражениях.

Методика И-ИЛИ дерева

Я же предлагаю сложные логические выражения оформлять в виде И-ИЛИ дерева. Под И-ИЛИ деревом я подразумеваю дерево, нетерминальные узлы которого представляют собой группы (последовательности) одинаковых логических операций И или ИЛИ, а терминальные - остальные логические выражения. Хорошим примером такого дерева является отбор настроек компоновки данных, правда у него верхняя (корневая) группа всегда имеет тип "И". В случае встроенного языка мы этим не ограничены и можем использовать любой тип верхней группы. В рассмотренном примере как раз сверху расположена группа "ИЛИ".

1. Встаем на первую открывающую скобку и с помощью сочетания клавиш CTRL+] находим тело первого узла и переносим целиком в одну следующую строку с отступом относительно слова Если

Если
    ((НомерИзменяемойКолонки = "4") Или (НомерИзменяемойКолонки = "5"))
Или (((НомерИзменяемойКолонки = "7") Или (НомерИзменяемойКолонки = "8")
И (ГруппаРасчета = мИдГруппы7))) Тогда

2. Следующий логический оператор будет И или ИЛИ. Он и определяет тип группы этого уровня при условии что все группы обрамлены скобками. Для повышения наглядности вставляем в начало группы операцию с не нарушающим результат вычисления группы константным значением. Для И это будет ИСТИНА, а для ИЛИ это будет ЛОЖЬ. ИСТИНА не меняет результат конъюнкции (ИСТИНА И), и ЛОЖЬ не меняет результат дизъюнкции (ЛОЖЬ ИЛИ). Рассмотрим преобразование выражения примера к И-ИЛИ дереву.

Если Ложь
    Или ((НомерИзменяемойКолонки = "4") Или (НомерИзменяемойКолонки = "5"))
    Или (((НомерИзменяемойКолонки = "7") Или (НомерИзменяемойКолонки = "8")
    И (ГруппаРасчета = мИдГруппы7))) Тогда

3. Встаем на следующую открывающую скобку корневого уровня и повторяем шаг 1.

Если Ложь
    Или ((НомерИзменяемойКолонки = "4") Или (НомерИзменяемойКолонки = "5"))
    Или (((НомерИзменяемойКолонки = "7") Или (НомерИзменяемойКолонки = "8") И (ГруппаРасчета = мИдГруппы7))) Тогда

4. Слово Тогда для наглядности я переношу на отдельную строку с тем же отступом, что и Если, а все внутренние строки условия имеют больший отступ. Таким образом мы четко обозначаем начало и конец условия.

Если Ложь
    Или ((НомерИзменяемойКолонки = "4") Или (НомерИзменяемойКолонки = "5"))
    Или (((НомерИзменяемойКолонки = "7") Или (НомерИзменяемойКолонки = "8") И (ГруппаРасчета = мИдГруппы7)))
Тогда

5. Далее повторяем шаги 1-3 для всех вложенных узлов (условий в скобках). Следует заметить, автор оригинального выражения не все группы обрамил скобками и последние 2 оператора из числа образующих группы различны и не разделены скобками. В итоге получаем

Если Ложь
    Или (Ложь
        Или (НомерИзменяемойКолонки = "4")
        Или (НомерИзменяемойКолонки = "5"))
    Или (Ложь
        Или (НомерИзменяемойКолонки = "7")
        Или (Истина
            И (НомерИзменяемойКолонки = "8")
            И (ГруппаРасчета = мИдГруппы7)))
Тогда

6. Теперь нам становится понятно, что логическое выражение можно упростить. Все вложенные однотипные (И или ИЛИ) группы можно смело всегда поднимать в родительскую группу.

Если Ложь
    Или (НомерИзменяемойКолонки = "4")
    Или (НомерИзменяемойКолонки = "5")
    Или (НомерИзменяемойКолонки = "7")
    Или (Истина
        И (НомерИзменяемойКолонки = "8")
        И (ГруппаРасчета = мИдГруппы7))
Тогда

7. В таком виде уже можно довольно безопасно убрать скобки вокруг условий внутри строк. В итоге получаем

Если Ложь
    Или НомерИзменяемойКолонки = "4"
    Или НомерИзменяемойКолонки = "5"
    Или НомерИзменяемойКолонки = "7"
    Или (Истина
        И НомерИзменяемойКолонки = "8"
        И ГруппаРасчета = мИдГруппы7)
Тогда

Кажется, что в итоге получилось заметно более простое и наглядное выражение. В исходном выражении было 16 скобок, в преобразованном - всего 2.

По идее, как изначально оформлять логические выражение по этой методике уже должно быть понятно.

Хочу обратить ваше внимание на отсутствие унарной операции НЕ как типа группы. При желании конечно можно было бы ввести в методику и группу НЕ, но она слишком отличается от рассмотренных и я лично сторонник обходить ее стороной и опускать на самые нижние узлы.

 

Думаю, что эту методику можно успешно применять не только к встроенному языку 1С, но и многим другим языкам.

Использую эту методику уже много лет.

Плюсы:

- повышает наглядность выражения после некоторого привыкания
- облегчает рефакторинг, т.к. позволяет четко видеть пути упрощения (устранения избыточности) выражения
- облегчает отладку, т.к. позволяет быстро комментировать(выключать)/раскомментировать(включать) фрагменты выражения
- облегчает изменение порядка фрагментов выражения
- позволяет дописывать комментарии к каждому узлу дерева
- сокращает левые отступы, вложенность условий, количество строк в коде по сравнению с некоторыми другими подходами

Минусы:

- не все сразу понимают чисто оформительское назначение "Истина И" и "Ложь Или"
- уходит больше времени на начальное написание выражения
- выражение занимает большее число строк
- часто не оправдывает себя в простых выражениях
- автоформатирование кода выравнивает все строки условия по одной границе

Шаблоны

Для удобства написания сложных логических выражений по этой методике рекомендую добавить себе шаблоны

Условие с корневой группой "И" -

Если Истина
    И  
Тогда
КонецЕсли;

Условие с корневой группой "Или"

Если Ложь
    Или 
Тогда
КонецЕсли;

См. также

Комментарии
1. Осипов Сергей (fixin) 3641 21.09.12 10:36 Сейчас в теме
а не проще ли для этого примера по другому?

Если ((НомерИзменяемойКолонки = "4") Или (НомерИзменяемойКолонки = "5"))
Или (((НомерИзменяемойКолонки = "7") Или (НомерИзменяемойКолонки = "8")
И (ГруппаРасчета = мИдГруппы7))) Тогда
Расчет(ГруппаРасчета);

Условие = НомерИзменяемойКолонки = "4";
Условие = Условие ИЛИ НомерИзменяемойКолонки = "4";
Условие2 = НомерИзменяемойКолонки = "8" И ГруппаРасчета = мИдГруппы7;
Условие = Условие ИЛИ Условие2;

Дешево и сердито, я лично перешел на такой способ.
Вместо Условие2 лучше писать осмысленный текст, тогда еще и комментирование происходит, например УсловиеГруппыОсобыхРасчетов.
VladC#; rpgshnik; unmensch; Jogeedae; Lancelot-2M; sulfur17; daho; nsasov; Gasilin; su_mai; Rustig; brr; +12 Ответить
2. Сергей Старых (tormozit) 4523 21.09.12 11:14 Сейчас в теме
(1) В некоторых случаях такой подход действительно оправдан, но в большинстве случаев он излишне повышает "жесткость" логической конструкции.
3. Осипов Сергей (fixin) 3641 21.09.12 12:03 Сейчас в теме
(2) зато прозрачно и наглядно.
39. Андрей Ильин (su_mai) 88 13.12.14 09:50 Сейчас в теме
(1) А я думал, что он это ты :), ошибся :)))
66. user user (inf012) 07.07.17 06:43 Сейчас в теме
(1)
Условие = НомерИзменяемойКолонки = "4";
Условие = Условие ИЛИ НомерИзменяемойКолонки = "4";
Условие2 = НомерИзменяемойКолонки = "8" И ГруппаРасчета = мИдГруппы7;
Условие = Условие ИЛИ Условие2;

А что это за конструкция такая с несколькими равно в строке, не встречал ее в типовых конфах?
Как ее правильно читать, где написано?
75. Алексей Ситников (SiAl) 71 18.08.17 12:10 Сейчас в теме
(66) Переменная в 1С версии 8 может быть булевой переменной. А потому самый левый знак равно - это знак присваивания, а все дальнейшие знаки равно - это знаки сравнения.
4. Игорь Steelvan (Steelvan) 31 24.09.12 21:55 Сейчас в теме
В языке Дракон удобно визуализировать такие выражения.
Serg_1C(M); +1 Ответить
5. Владислав Мороз (vlad.frost) 172 26.09.12 00:56 Сейчас в теме
Цель рефакторинга - сделать код более читаемым. А вот это вот "ЕСЛИ Ложь ИЛИ НомерИзменяемойКолонки = "4"" у меня уже выворачивает мозги наизнанку.

Я бы написал так:

ВыполнитьРасчетПоНомеруКолонки(ГруппаРасчета, НомерИзменяемойКолонки, мИдГруппы7); // Выделили метод

Процедура ВыполнитьРасчетПоНомеруКолонки(ГруппаРасчета, НомерИзменяемойКолонки, мИдГруппы7)

  Если НомерИзменяемойКолонки = "4" Или НомерИзменяемойКолонки = "5" Тогда
    Расчет(ГруппаРасчета);
    Возврат;
  КонецЕсли;

  Если ГруппаРасчета <> мИдГруппы7 Тогда // Инвертируем условие
    Возврат;
  КонецЕсли;

  Если НомерИзменяемойКолонки = "7" Или НомерИзменяемойКолонки = "8" Тогда
    Расчет(ГруппаРасчета);
  КонецЕсли;

КонецПроцедуры;
Показать


Согласитесь, так читается ещё легче.
wolfsoft; Fressten; NN2P; Lacrimosa0000; kharuz; sulfur17; savchenkodenis; SunShinne; корум; Chernik; asf-trade; bdvtdviking; Tolpinski; iTony73; Rustig; +15 Ответить
6. Сергей Старых (tormozit) 4523 26.09.12 01:19 Сейчас в теме
(5) Возможно проблема только в адаптации мышления к элементарным приемам из булевой алгебры для тех кто с ней не знаком. Истина не меняет результат конъюнкции (ИСТИНА И), и Ложь не меняет результат дизъюнкции (ЛОЖЬ ИЛИ).
Обрати внимание, я не предлагал их записывать в одну строку специально чтобы увеличить наглядность. Так что ты исказил мою методику.
zqzq; pbabincev; sulfur17; hulio; dgolovanov; METAL; borodatii; AzagTot; NittenRenegade; e-sin; EmpireSer; vasiliy_b; aspirin4eg; +13 1 Ответить
8. Владислав Мороз (vlad.frost) 172 26.09.12 12:49 Сейчас в теме
(6) Вот представьте, инженер техподдержки, ему 35 лет. Он булеву алгебру учил двадцать лет назад в школе. У него ещё десять заявок в очереди и злой пользователь на линии. И вот он смотрит на ваш код и пытается понять, что же значит ваше семиэтажное выражение. Каковы шансы, что он легко поймёт, что вы имели ввиду, когда писали этот код?

Возможно, ваше выражение тождественно первоначальному, но легче читать его не стало.
wolfsoft; VladC#; Brawler; RailMen; unmensch; SkyHunter; sulfur17; alvabul; +8 1 Ответить
9. Осипов Сергей (fixin) 3641 26.09.12 13:13 Сейчас в теме
(8) полностью согласен. Тормоз, ты нарушаешь принцип KISS.
10. Сергей Старых (tormozit) 4523 26.09.12 13:52 Сейчас в теме
(8), (9)
Это обычные споры для рефакторинга.
Выносить ли в отдельную функцию фрагмент кода, который с большой вероятностью будет вызван только в одном месте?
Оформлять ли в виде отдельной переменной выражение, которое с большой вероятностью будет использовано только в одном месте?
Выносить ли во временную таблицу пакета подзапрос, который с большой вероятностью будет использован только в одном месте?

Ответ на такие вопросы (абстаригуясь от специфики запросов к данным) обычно
- Да, если фрагмент настолько большой или сложный, что затрудняет восприятие/чтение/понимание логики программы.
- Нет - в остальных случаях, т.к. для человека последовательное с фиксацией промежуточных результатов в виде отдельных переменных чтение программы труднее.

Таким образом если есть возможность сохраняя приемлемую читаемость программы отказаться от лишних промежуточных переменных, то я рекомендую ее использовать. В случае сложных логических выражений этого помогает достичь предлагаемая методика.
zqzq; sulfur17; CratosX; palsergeich; +4 1 Ответить
40. Андрей Ильин (su_mai) 88 13.12.14 09:53 Сейчас в теме
(10) tormozit, Все неверно! Читай про процедурную декомпозицию кода: https://ru.wikipedia.org/wiki/%D0%94%D0%B5%D0%BA%D0%BE%D0%BC%D0%BF%D0%BE%D0%B7%D0­%B8%D1%86%D0%B8%D1%8F.
83. Валерий К (klinval) 228 06.09.17 14:43 Сейчас в теме
Первоначальный вариант естественно плох.
Но я дольше буду вникать в выражение:
Если Ложь
    Или НомерИзменяемойКолонки = "4"
    Или НомерИзменяемойКолонки = "5"
    Или НомерИзменяемойКолонки = "7"
    Или (Истина
        И НомерИзменяемойКолонки = "8"
        И ГруппаРасчета = мИдГруппы7)
Тогда
Показать

Чем в:
ИзменилиРасчетнуюКолонку = (НомерИзменяемойКолонки = "4" Или НомерИзменяемойКолонки = "5" Или НомерИзменяемойКолонки = "7");
ИзменилиКолонку8ИГруппаРасчетаВерная = (НомерИзменяемойКолонки = "8" И ГруппаРасчета = мИдГруппы7);
НеобходимРасчет = ИзменилиРасчетнуюКолонку Или ИзменилиКолонку8ИГруппаРасчетаВерная;
Если НеобходимРасчет Тогда
	Расчет(ГруппаРасчета);
КонецЕсли;

//Можно заранее колонки 4,5,7 вывести в переменную МассивРасчетныхКолонок и искать по нему. 
//ИзменилиРасчетнуюКолонку = МассивРасчетныхКолонок.Найти(НомерИзменяемойКолонки)<>Неопределено;
Показать

Просто прочитав название переменной всё становиться понятно и в правую часть (после знака =) можно не смотреть.

Дальше форматировать вариант с переменными можно под себя (под свой вкус или стиль). Допустим:
ИзменилиРасчетнуюКолонку = 
	(НомерИзменяемойКолонки = "4" Или НомерИзменяемойКолонки = "5" Или НомерИзменяемойКолонки = "7");
ИзменилиКолонку8ИГруппаРасчетаВерная = 
	(НомерИзменяемойКолонки = "8" И ГруппаРасчета = мИдГруппы7);
НеобходимРасчет = ИзменилиРасчетнуюКолонку Или ИзменилиКолонку8ИГруппаРасчетаВерная;
Если НеобходимРасчет Тогда
	Расчет(ГруппаРасчета);
КонецЕсли;

Или в Вашем стиле:
ИзменилиРасчетнуюКолонку =	Ложь
							Или НомерИзменяемойКолонки = "4" 
							Или НомерИзменяемойКолонки = "5" 
							Или НомерИзменяемойКолонки = "7";
ИзменилиКолонку8ИГруппаРасчетаВерная =	Истина
										И НомерИзменяемойКолонки = "8" 
										И ГруппаРасчета = мИдГруппы7;
НеобходимРасчет =	Ложь
					Или ИзменилиРасчетнуюКолонку 
					Или ИзменилиКолонку8ИГруппаРасчетаВерная;
Если НеобходимРасчет Тогда
	Расчет(ГруппаРасчета);
КонецЕсли;
Показать

(10)
Таким образом если есть возможность сохраняя приемлемую читаемость программы отказаться от лишних промежуточных переменных, то я рекомендую ее использовать.

Если в конкретном случае использование промежуточных переменных улучшает читаемость (путь даже незначительно: на 2-10 секунд меньше вникать в код), то почему-бы это не использовать?
rpgshnik; mvxyz; kraynev-navi; Артано; +4 Ответить
84. Сергей Старых (tormozit) 4523 15.09.17 23:05 Сейчас в теме
(83) Если есть время, желание и условие пишется с нуля либо полностью понятно, то так писать конечно в целом лучше. Однако строк получится заметно больше и вероятность внести ошибку выше. Также для не с нуля написанного выражения придется досконально разобраться во всех деталях условия, чтобы не испортить его восприятие привнесенной семантикой новых переменных. Мой же способ позволяет рефакторить и оформлять даже вообще непонятные условия с минимальным риском повреждения их логической и без риска повреждения семантической структуры.
klinval; mvxyz; +2 Ответить
7. shrekerererer (StepanZaytsev) 26.09.12 02:24 Сейчас в теме
я конечно не претендую на мнение авторитетное, но не проще ли все делать логическими схемами, еще с курса информтики так все делали, чем придумывать новые схемы?? это как на программировние
rpgshnik; +1 Ответить
11. г. Казань Рустем Гумеров (Rustig) 831 26.09.12 22:29 Сейчас в теме
ТормозАйти, у тебя наверняка есть еще какие-нибудь трюки, способы, личные методики программирования (разработки). Мне интересно и полезно читать как саму идею публикации, так и шлейф комментариев. :) так что просим на бис :)
mvxyz; sulfur17; METAL; kuzyara; Созинов; +5 Ответить
12. Тимофей Чернов (software1c) 1 26.09.12 23:27 Сейчас в теме
Плюс автору. За методику ФОРМАТИРОВАНИЯ кода. Однозначно, четко и понятно даже пятикласснику
sulfur17; METAL; NittenRenegade; +3 1 Ответить
13. Александр Алёхин (new_user) 206 05.10.12 16:16 Сейчас в теме
Че-т какие-то комментарии неоднозначные! Мне очень приемчик понравился, активно использую его в практике! Автору спасибо!..
RaketaSoft; +1 Ответить
14. Олег Пендраковский (aspirin4eg) 08.10.12 15:54 Сейчас в теме
Применять булеву алгебру, на мой взгляд, следует именно для упрощения логических конструкций и исключения ненужных проверок в условиях. Иначе она несет только усложнение. Восприятие скобок облегчается если их записывать правильно. Тогда кстати и читаемость условий намного упрощается.
15. Андрей Калякин (kalyaka) 116 10.10.12 09:23 Сейчас в теме
Форматирование однозначно повышает читаемость! Убрать бы еще лишние слова "Истина" и "Ложь" и будет вообще отлично.
16. Сергей Старых (tormozit) 4523 10.10.12 09:34 Сейчас в теме
(15) В таком случае ты не сможешь просто закомментировать первое условие в каждой группе и сохранить синтаксическую корректность.
Gluk_1C; sulfur17; Spec1c82; +3 Ответить
86. Андрей Калякин (kalyaka) 116 25.10.17 10:00 Сейчас в теме
(16)Перечитал еще раз, идея понравилась :)
87. Сергей Старых (tormozit) 4523 25.10.17 10:35 Сейчас в теме
(86) Лучше поздно, чем никогда =)
17. EfiopReal (Созинов) 10.10.12 17:13 Сейчас в теме
За заметку +. Было бы неплохо почитать об улучшении читаемости кода, если есть еще методики, а то недавно свой код годовой давности правил - был в шоке. Да и сейчас зачастую пишу такое, что потом себе руки отрезать хочется :-)
amon_ra; Ворчун; +2 Ответить
18. Владислав Мороз (vlad.frost) 172 10.10.12 17:35 Сейчас в теме
19. Александр Хомяк (logarifm) 994 11.10.12 12:24 Сейчас в теме
Мозговынос и не нахожу в таких условиях ничего кроме трудностей их отладки и восприятия. Мое ИМХО - обойтись гораздо проще и более эфективно написав несколько упрощенных условий чем одно но с сумасшедшшей структурой. Не оправдано это... Остаюсь при своем мнении и не ставлю ни плюса ни минуса.

ЗЫ. охота было влипить минус но остановило лишь то, что автор знает о чем пишет и это труд. А минус за сложность и не рациональное использование таких выражений. (Игра слов)
VladC#; rpgshnik; Anchoret; корум; aspirin4eg; mrXoxot; const000; Yashazz; dj_serega; zikonza; ffgnebel; klinval; Sashko773; Manticor; Tedman; DrAku1a; Craig; OVladius; Evil Beaver; igor-pn; Eillecho; vlad.frost; +22 2 Ответить
20. Эстер Коган (e.kogan) 1827 29.08.13 12:17 Сейчас в теме
(19) logarifm, лично мне приятнее читать грамотный и структурированный текст, чем конструкции вроде "Мое ИМХО - обойтись гораздо проще и более эфективно написав несколько упрощенных условий чем одно но с сумасшедшшей структурой. Не оправдано это..."

//SARCAZM//
21. Александр Хомяк (logarifm) 994 29.08.13 12:38 Сейчас в теме
(20) e.kogan, А в чем не граммотность опридиления условий в простом виде:

Если Тогда
Если Тогда
Если Тогда

и т.п.
КонецЕсли;

Причем здесь конструктивность языка вообще!? Тебе как минимум сюда или наподобие этого:
читать книги С.Макконнелла "Совершенный код". Вообще не путай статью автора из структурированным кодом!
VladC#; kharuz; +2 1 Ответить
22. Эстер Коган (e.kogan) 1827 29.08.13 13:47 Сейчас в теме
(21) logarifm, спасибо, Стива Макконнелла читала. Я про чистоту и системность мышления, выражающуюся не только в программном коде, но и в естественном языке. А с этим у вас определённо проблемы.
24. Андрей Акулов (DrAku1a) 1219 21.11.13 04:03 Сейчас в теме
(21)
Если ТипЗнч(Объект)=Тип("СправочникСсылка.Номенклатура") Тогда
Если НЕ Объект.Пустая() Тогда
...
КонецЕсли
КонецЕсли;
43. Данила Елистратов (CagoBHuK) 27 29.05.15 09:27 Сейчас в теме
(21) logarifm, внутри каждого Если придется повторять один и тот же код.
23. Александр Хомяк (logarifm) 994 29.08.13 13:55 Сейчас в теме
на просторы интернета.... ахахах смешно. Облегчу с поиском:
И́МХО или ИМХО́ (от англ. IMHO, In My Humble Opinion), также имхо или imho (строчными буквами) — русская транслитерация английского акронима, означающего «по моему́ скромному мнению» .

Область использования сокращения — эхоконференции, форумы, чаты, и другие (как публичные, так и частные) места для выражения своего отношения к какому-нибудь предмету. В разговорной речи встречается относительно редко.
25. Yan Tsys (YanTsys) 10 21.11.13 13:18 Сейчас в теме
(23) logarifm, думаю проблема не в "ИМХО", а в формулировке "обойтись гораздо проще и эфективно", для того чтобы понять какой смысл вы заложили в предложение попробуйте составить обратное. Как оно будет звучать: "обойтись сложнее и неэффективно"?
Кроме того:
"влИпить",
"статью автора ИЗ структурированным кодом",
"сумасшедшШей",
"опрИдИления".

Ну и на вопрос:
"А в чем не граммотность опридиления условий в простом виде:
Если Тогда
Если Тогда
Если Тогда
и т.п.
КонецЕсли;
"

1С при проверке на такой код выдаст ошибку:
err: Ожидается ключевое слово 'КонецЕсли'

Граммотно писать:
Если Тогда
ИначеЕсли Тогда
ИначеЕсли Тогда
и т.п.
КонецЕсли;

И если девушка читала Стива Макконнелла то с вашей стороны будет "наивно" полагать, что она не понимает значение вашего "ИМХО", и проверьте на приборах скромность вашего мнения, лично мне кажется вы его недооцениваете :)
teploukhov; +1 Ответить
26. Александр Хомяк (logarifm) 994 21.11.13 13:29 Сейчас в теме
Ой, а я просто и не знал, что там ошибка, а еще ошибка в том что в условиях нет логических выражений и что?
27. Антон Бордачев (iTony73) 25.11.13 17:17 Сейчас в теме
А как же ?(Условие, истина, Ложь), на наглядно?
Так же для простоты и наглядности можно использовать соответствие, то есть заводить несколько вариантов, а потом небольшим условием его обходить.
28. Игорь Чайкин (ЧИА) 150 04.02.14 13:35 Сейчас в теме
не буду придираться к коду
придерусь к идее

как приверженец написания кода через отладчик, считаю, что
1. условия должны быть простыми
2. везде должно быть место точке останова

таким образом, надо писать не одну дикую проверку
и не структуру типа

Если Тогда
ИначеЕсли Тогда
ИначеЕсли Тогда
КонецЕсли;

а структуру типа

Если Тогда

Если Тогда
Иначе
КонецЕсли;

Иначе

Если Тогда
Иначе
КонецЕсли;

КонецЕсли;
29. Сергей Старых (tormozit) 4523 04.02.14 13:48 Сейчас в теме
(28) Чтобы было более наглядно, приведи свой вариант кода для примера из статьи.
30. Игорь Чайкин (ЧИА) 150 04.02.14 15:12 Сейчас в теме
НадоСчитать = Ложь;

Если ГруппаРасчета = мИдГруппы7 Тогда

Если (НомерИзменяемойКолонки = "8") Тогда
    НадоСчитать = Истина;
Иначе
    //
КонецЕсли;

Иначе

Если 
    (НомерИзменяемойКолонки = "7") 
    Или 
    (НомерИзменяемойКолонки = "4")
    Или 
    (НомерИзменяемойКолонки = "5")
    Тогда
    НадоСчитать = Истина;
Иначе
    //
КонецЕсли;

КонецЕсли;

Если НадоСчитать  Тогда
    Расчет(ГруппаРасчета);
КонецЕсли;

Показать
32. Сергей Старых (tormozit) 4523 04.02.14 16:19 Сейчас в теме
(30) Сразу видно дублирование кода "Расчет(ГруппаРасчета);". Подумай что будет, если там не одна строка будет, а 30 например =)
33. Игорь Чайкин (ЧИА) 150 04.02.14 16:23 Сейчас в теме
(32) tormozit,
что будет, если там не одна строка будет, а 30 например

если в блоке больше 8 строк (требования моих наставников), ну или 16 (один экран, мои), это или процедура, или функция

переделал с одним запуском
38. Илья Вольных (xFoG) 09.07.14 10:43 Сейчас в теме
(30) ЧИА,
таким образом, надо писать не одну дикую проверку
и не структуру типа

Если Тогда
ИначеЕсли Тогда
ИначеЕсли Тогда
КонецЕсли;

а структуру типа

Если Тогда

Если Тогда
Иначе
КонецЕсли;
Показать

В первом случае после получения истины мы остальные проверки не проводим, во втором - проверяем все, что увеличивает время выполнения участка кода.
(31) ЧИА,
запросы рекомендую писать не через вложенные
а через временные таблицы

и отлаживать проще
и нагляднее

Простота отладки сомнительна. Скопировать текст вложенного запроса в консоль проще.
(33) ЧИА
если в блоке больше 8 строк (требования моих наставников), ну или 16 (один экран, мои), это или процедура, или функция

Всегда считал, что единственным условием является множественность использования блока, а не размер. Каким же шрифтом вы пишите, что у вас 16 строк на экран умещается?
31. Игорь Чайкин (ЧИА) 150 04.02.14 15:39 Сейчас в теме
по тем же причинам

запросы рекомендую писать не через вложенные
а через временные таблицы

и отлаживать проще
и нагляднее

и быстрее обычно выполняется
34. Разве это имеет значение (-fox-) 05.02.14 09:07 Сейчас в теме
По мне, если условие сложное, его всегда можно разбить на более простые + сделать грамотные комментарии.
sergey484; +1 Ответить
35. Елена Ситникова (lesenoklenok) 19 07.02.14 09:54 Сейчас в теме
Спасибо за идею, но мне кажется что итоговый вариант как то смотрится сложнее. Ну это только лишь мое мнение.
36. poyson (poyson) 24.03.14 14:40 Сейчас в теме
Чтоб понять надо вникнуть :). В целом интересный подход. Спасибо.
37. Александр Пряшников (Пан) 6 24.05.14 12:51 Сейчас в теме
любая структуризация полезна, спасибо
41. You Name (YouName) 13.12.14 23:24 Сейчас в теме
Мне этот метод понравился! Возьму на вооружение.
По мне любой метод найдёт своего "пользователя".
42. Павел Жихарев (palsergeich) 19.02.15 15:42 Сейчас в теме
Это как стенография, овладевшим все понятно, но конкретно меня количество скобочек еще никогда не смущало, а вот такая запись нормально прочиталась с 5го раза и не факт что другое выражение я прочитаю с 1ой попытки.
Метод интересный, но увы, мне за такое оторвут пальцы.
Просто показал товарищу конечное выражение, он мне в ответ скинул картинку, как он это видит.

Таки код должен быстро читаться не только Вами но и другими. А стандартное написание подразумевает запись в исходном виде.
44. Kiber_ Юрий (Kiber_) 11 02.06.15 17:19 Сейчас в теме
По поводу группировки логических выражений в блоки на основе "одинаковых логических операций" - целиком согласен с автором.
Но как-то показался очень сложным процесс раскрытия скобок.
Также не понравились "Ложь" и "Истина" в качестве первого операнда блока.
Сам-бы написал так:
Если НомерИзменяемойКолонки = "4"
	Или НомерИзменяемойКолонки = "5"
	Или НомерИзменяемойКолонки = "7"
	Или (НомерИзменяемойКолонки = "8" И ГруппаРасчета = мИдГруппы7) Тогда
	Расчет(ГруппаРасчета);
КонецЕсли;
inf012; drjc; sulfur17; +3 Ответить
45. Сергей Старых (tormozit) 4523 02.06.15 19:40 Сейчас в теме
(44) Так плохо отличим конец условия от начала кода под условием.
46. Dyuha K (dyuha) 30.08.15 04:17 Сейчас в теме
У этого метода два офигенных плюса:
Можно быстро закомментировать любое условие;
При отладке и точку останова можно поставить в любом месте, и шагать по F10/F11 удобней.
mvxyz; sulfur17; Spec1c82; +3 Ответить
47. spec spec (Spec1c82) 04.09.15 13:07 Сейчас в теме
Сначала глянул только исходное условие и конечный результат. Сразу не понял зачем нужны "Если Ложь ИЛИ" и "Если Истина И". Пришлось прочитать полностью и после осмысления понял всю красоту предлагаемого решения.
Очень наглядно было сравнение с отбором настроек компоновки данных.
Удобно что легко можно закомментировать любое из условий, в том числе и первое. Соответственно отладка тоже упрощается.
Впрочем порой красоту структуры в целях оптимизации придется нарушить и в первую очередь проверять наиболее вероятные условия (если есть такое понимание или статистика).
dgolovanov; +1 Ответить
48. Виктор (vvirus) 19 18.09.15 07:45 Сейчас в теме
Красивый подход ,
использую такой вариант записи

(+) при переходе на динамические условия "открытый" ИЛИ не блокирует дополнительные условия
(+) сохраняеться история введения ограничений
(-) читаеться возможно сложнее чем вариант топик стартера

Если (
(НомерИзменяемойКолонки = "4")
Или (НомерИзменяемойКолонки = "5")
)
Или (
(
(НомерИзменяемойКолонки = "7")
Или (НомерИзменяемойКолонки = "8")
И (ГруппаРасчета = мИдГруппы7)
)
)
Тогда
Расчет(ГруппаРасчета);
КонецЕсли;



но и это у меня не оптимизация, а лёгкое упрощение чтения

если за оптимизацию то необходимость расчёта ожидается в свойствах колонки и(или) в свойствах группы

то есть ...


Если ( ТекИзменяемаяКолонка.Рассчет ИЛИ ТекГруппаРасчета.Рассчет )
Тогда Расчет(ТекГруппаРасчета);
КонецЕсли;

Разумеется группа условий содержащая ИЛИ всегда в скобках
49. Яков Коган (Yashazz) 2138 01.10.15 14:00 Сейчас в теме
Уникально редкий случай, когда я склонен согласиться с fixin'ом. Сложную логику надо не переписывать так, этак и разэдак, а упрощать. Реальным упрощением является грамотное использование промежуточных переменных, это и отлаживать легче.
50. Сергей Старых (tormozit) 4523 01.10.15 14:21 Сейчас в теме
(49) Ну это тот же холивар "алгоритмическое или декларативное", "пакет из 10 запросов или один сложный запрос". Я показал для тех, кто предпочитает декларативный стиль, как на мой взгляд оптимальнее оформлять такие выражения. Любители алгоритмического стиля могут конечно результат каждой логической операции помещать в отдельную переменную и давать ей семантически качественное имя =), но это тоже крайность. Так что хороший разработчик должен уметь грамотно сочетать эти подходы и не "холиварить".
hydro2588_2015; hulio; NittenRenegade; dgolovanov; Гриффин; +5 Ответить
51. Владимир Попов (NittenRenegade) 65 30.10.15 16:08 Сейчас в теме
В начале мне запись не понравилась, т.к. и исходную я прочитал совершенно без труда. В отличие от вариантов людей, предлагавших разбивать на какие-то вызываемые части.
Однако после комментария software1c вернулся к получившейся записи и понял её. Действительно, для сложных условий запись отличная.
52. Гость 16.11.15 15:15 Сейчас в теме
Интересная статья + нашел для себя несколько интересных способов оформления в комментариях.
Вывод:
+ Не приветствуются собственные велосипеды (Если Ложь Или...)
+ Условие 1го уровня - 1 таб, 2го уровня 2 таб и т.д. для читабельности
+ Одно условие = одна строка, для возможности быстро закомментировать

Если
	НомерИзменяемойКолонки = "4" Или
	НомерИзменяемойКолонки = "5" Или
	НомерИзменяемойКолонки = "7" Или
	( НомерИзменяемойКолонки = "8" И ГруппаРасчета = мИдГруппы7 )
Тогда
	// ...
КонецЕсли;
Показать
53. Илья Вольных (xFoG) 18.11.15 11:02 Сейчас в теме
(52) HardCoder,
Только "ИЛИ" в твоем примере хорошо бы писать перед тем выражением, к которому оно относится. Как и запятые и т.д.
Тогда, удалив или закомментив строку, ты не пролучишь ругань на лишнее "ИЛИ".
54. Решитко Дмитрий (grumagargler) 327 31.12.15 01:59 Сейчас в теме
а почему просто не убрать лишние скобки?

	Если (НомерИзменяемойКолонки = "4"
		Или НомерИзменяемойКолонки = "5"
		Или НомерИзменяемойКолонки = "7")
		Или (НомерИзменяемойКолонки = "8"
			И ГруппаРасчета = мИдГруппы7) Тогда
		//...
	КонецЕсли;


плюс, если уж заботится о качестве кода, допускать трехсловные идентификаторы нельзя.
А если нужен идентификатор из трех слов, то значит сам контекст уже кандидат на рефактор и разбиение на более мелкие функции.
rpgshnik; klinval; e-sin; +3 Ответить
58. Сергей Есин (e-sin) 2 10.02.16 21:08 Сейчас в теме
(54) grumagargler,
Лучше совсем убрать.

Если НомерИзменяемойКолонки = "4"
	Или НомерИзменяемойКолонки = "5"
	Или НомерИзменяемойКолонки = "7"
	Или НомерИзменяемойКолонки = "8" И ГруппаРасчета = мИдГруппы7 Тогда
		//...
КонецЕсли;
rpgshnik; klinval; dg15000; +3 Ответить
55. Матти Нюкянен (Nykyanen) 216 13.01.16 09:24 Сейчас в теме
За часть про оформление (+) за часть про Рефакторинг (-).
Ведь даже школьник знает что выражения типа: А или Б или В = не (не А и не Б и не В)
Решать такой пример легче и человеку и машине, так как при использовании только И без ИЛИ и получении первой ложь все выражение в скобках будет ложь.
Особенно это важно в запросах. Так как ИЛИ в секции ГДЕ запроса при выполнении выполнит два запроса с каждым из условий и сделает их объединение.

Вывод идем учить преобразования логических выражений, кто ещё не в курсе что это такое.
SunShinne; +1 Ответить
56. Сергей Старых (tormozit) 4523 13.01.16 09:52 Сейчас в теме
(55) Nykyanen,
Ведь даже школьник знает что выражения типа: А или Б или В = не (не А и не Б и не В)

Судя по комментам здесь, это ошибочное утверждение. Не уверен, что мысль твою про рефакторинг я понял. Ты предлагаешь вообще не использовать оператор ИЛИ что ли? Если так то почему он есть во всех языках, раз он такой вредный и избыточный?
57. Матти Нюкянен (Nykyanen) 216 13.01.16 14:31 Сейчас в теме
(56) Цель рефакторинга — сделать код программы легче для понимания. В основе рефакторинга лежит последовательность небольших эквивалентных (то есть сохраняющих поведение) преобразований.

Я хотел добавить, что выполнив логические преобразования выражений можно упростить понимание и так же часто получается повысить скорость работы. Согласен, что не всегда замена всех ИЛИ на И упростит запись и понимание, но на моей практике в 80% случаев замена ИЛИ на И упрощает понимание. Так же в процессе логические преобразования оказывается, что некоторые из выражений не влияют на результат всего выражения и/или можно сократить повторяющиеся выражения.

Конечно ИЛИ имеет право на жизнь как и много чего другого. Тут как с сортировкой можно в лоб сортировать, а можно пузырьком или еще каким то более хитрым методом.

Вот пример преобразования выражения из статьи.
((НомерИзменяемойКолонки = "4") Или (НомерИзменяемойКолонки = "5"))
Или (((НомерИзменяемойКолонки = "7") Или (НомерИзменяемойКолонки = "8")
И (ГруппаРасчета = мИдГруппы7))) | {замена на буквы по порядку на АБВГД} |
(А ИЛИ Б) ИЛИ (В ИЛИ (Г И Д)) =
А ИЛИ Б ИЛИ В ИЛИ (Г И Д) =
НЕ(НЕ А И НЕ Б И НЕ В И НЕ(Г И Д)) =
НЕ(НЕ(НомерИзменяемойКолонки = "4") И НЕ(НомерИзменяемойКолонки = "5") И НЕ(НомерИзменяемойКолонки = "7") И НЕ((НомерИзменяемойКолонки = "8") И (ГруппаРасчета = мИдГруппы7))) =
НЕ(НомерИзменяемойКолонки <> "4"
И НомерИзменяемойКолонки <> "5"
И НомерИзменяемойКолонки <> "7"
И НЕ((НомерИзменяемойКолонки = "8") И (ГруппаРасчета = мИдГруппы7)))

Так как в скобках все через И а за скобками НЕ, тогда если хотя бы одно выражение равно ЛОЖЬ в скобках, тогда и все выражение в скобках равно ЛОЖЬ, а все выражение равно ИСТИНА. Пример, НомерИзменяемойКолонки = 5, тогда все выражение в скобках равно ложь, а все выражение равно истина.
59. Максим Бурляев (maks_20) 15 01.03.16 11:03 Сейчас в теме
Пользуюсь такой методикой. Солидарен с автором - удобно, наглядно, читабельно. Стоит один раз понять всю логику и потом уже проблем не будет.
rpgshnik; dgolovanov; +2 Ответить
60. Эльдар Гамзаев (lunjio) 43 28.08.16 23:17 Сейчас в теме
книга "Совершенный код", совет автора - объединять такие условия в логически понятные группы, вместо НомерИзменяемойКолонки = "4" вынести предварительно в отдельную переменную и писать ПользовательМеняетКолонкуЦена = НомерИзменяемойКолонки = "4", а в условиях уже будет Если ПользовательМеняетКолонкуЦена ИЛИ ПользовательМеняетКолонкуСумма и т.д, сейчас такие процессоры, что нужно идти в сторону удобночитаемости кода, и не заморачиваться на том, что выполнится пару лишних условий в жертву удобночитаемости и логического смысла кода.
invertercant; klinval; корум; +3 Ответить
61. Юрий К (Юрий-К) 71 12.01.17 08:08 Сейчас в теме
Давно делаю как Сергей, еще с Дельфи осталась такая традиция,

также "привил" себе привычку скобки подряд не ставить - "((", или разреживать скобки пробелами " ( ( " или разносить на разные строки, читаемость повышается.

пример
было  Если ((НомерИзменяемойКолонки = "4") Или (НомерИзменяемойКолонки = "5"))

Стало Если (
                        (НомерИзменяемойКолонки = "4") Или (НомерИзменяемойКолонки = "5")
                    )
62. Oleg Space (spacecraft) 12.01.17 08:34 Сейчас в теме
(61) для меня более читабелен первый вариант.
Второй размазанный по странице получается. А если учитывать, что в нем блок кода еще, то на страницу может не поместиться. Тогда совсем не читабельно получается.
63. Николай Щербаченко (romasna) 209 11.04.17 15:25 Сейчас в теме
Мне нравятся такие штучки, улучшающие обзор кода. Всегда отдавал предпочтение структуре логического выражения
Если <Начало условия >
     <Продолжение условия>
Тогда
    <Блок операторов>
КонецЕсли

А из этой статьи узнал еще о некоторых простых приемах, улучшающих понимание сложных выражений. Спасибо автору.
Вот только одна незадача: фирма 1С не приветствует такое структурирование логического выражения и после авто-форматирования блока программного кода вся наша красотища превращается в (на примере автора статьи)
Если Ложь
    Или НомерИзменяемойКолонки = "4"
    Или НомерИзменяемойКолонки = "5"
    Или НомерИзменяемойКолонки = "7"
    Или (Истина
    И НомерИзменяемойКолонки = "8"
    И ГруппаРасчета = мИдГруппы7)
    Тогда
    Расчет(ГруппаРасчета);
КонецЕсли;
Показать

Меня всегда раздражало это маленькое недоразумение... :)
64. www2000 www2000 (www2000) 53 25.04.17 13:23 Сейчас в теме
Еще можно добавить, что такой стиль оформления позволяет безболезненно закомментировать один из элементов условия. Но для этого надо последнию скобку таже переносить на отдельную строку.
65. Сергей Старых (tormozit) 4523 28.05.17 23:56 Сейчас в теме
Конструктор запроса из подсистемы "Инструменты разработчика" теперь по умолчанию использует описанный в статье иерархический стиль (и-или дерево) сборки условий отбора и соединений.
67. Arthur Gambler (Release) 07.07.17 07:12 Сейчас в теме
Левой переменной присваивается результат сравнения: Результат = (ПервоеЗначение = ВтороеЗначение), подобно: Результат = ПервоеЗначение <> ВтороеЗначение или Условие2 = НомерИзменяемойКолонки <> "8".
68. binx (binx) 11.07.17 07:31 Сейчас в теме
На мой взгляд если много условий,то это не очень хорошо и плохо читаемо в любом случае как не форматируй.
69. Вячеслав (slawa) 24 26.07.17 10:26 Сейчас в теме
Чем больше пользуюсь - тем больше позитива от этого метода.
Попробуйте.

Например:
Для каждого эл Из Объект.Товары Цикл
	Если Ложь
		ИЛИ (Истина
			И ИспользуетсяОСНО 
			И эл.СчетУчета = ПланыСчетов.Хозрасчетный.ИнвентарьИХозяйственныеПринадлежностиВЭксплуатации)  // МЦ.04
		ИЛИ (Истина
			И ИспользуетсяОСНО 
			И эл.СчетУчета.Родитель = ПланыСчетов.Хозрасчетный.Материалы // 10
			И эл.СчетУчета.ВидыСубконто.Найти(ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.Склады) <> Неопределено)
	Тогда
		НужноСоздатьПоступлениеМЦ = Истина;
	Иначе
		НужноСоздатьПоступлениеМЦ = Ложь;
		Прервать;
	КонецЕсли; 
КонецЦикла;
Показать
70. Денисов Евгений (Devi) 15 03.08.17 06:17 Сейчас в теме
Народ - я один что-ли это заметил?

Если ((НомерИзменяемойКолонки = "4") Или (НомерИзменяемойКолонки = "5"))
Или (((НомерИзменяемойКолонки = "7") Или (НомерИзменяемойКолонки = "8")
И (ГруппаРасчета = мИдГруппы7))) Тогда
    Расчет(ГруппаРасчета);
КонецЕсли;


Ну ни как не однозначно
Если Ложь
    Или НомерИзменяемойКолонки = "4"
    Или НомерИзменяемойКолонки = "5"
    Или НомерИзменяемойКолонки = "7"
    Или (Истина
        И НомерИзменяемойКолонки = "8"
        И ГруппаРасчета = мИдГруппы7)
Тогда


Всеми этими оптимизациями угробили логику работы

Аналог карявками автора это будет:

Если Ложь
    Или НомерИзменяемойКолонки = "4"
    Или НомерИзменяемойКолонки = "5"
    Или (Истина
        И   НомерИзменяемойКолонки = "7"
        И ГруппаРасчета = мИдГруппы7)
    Или (Истина
        И НомерИзменяемойКолонки = "8"
        И ГруппаРасчета = мИдГруппы7)
Тогда
Показать


Так что РАЗ НИ КТО ЭТОГО ДАЖЕ НЕ УВИДЕЛ эта "оптимизация" и "наглядность" под БОЛЬШИМ сомнением!
71. Сергей Старых (tormozit) 4523 03.08.17 07:02 Сейчас в теме
(70) Да, ты один смог так ошибиться. Проверь что выдаст оригинал и что выдаст твой вариант при НомерИзменяемойКолонки = "7" и ГруппаРасчета <> мИдГруппы7 . Их поведение будет различным. Обрати внимание на приоритеты логических операций. А ИЛИ Б И В эквивалентно А ИЛИ (Б И В), а не (А ИЛИ Б) И В.
sasha777666; +1 Ответить
72. Денисов Евгений (Devi) 15 03.08.17 07:15 Сейчас в теме
(71) Раскрой скобки ещё раз ВНИМАТЕЛЬНЕЕ как раз логику работы ты сломал... Скобочки во второй и третьей строчке верхнего примера говорят что эти строчки возможны только при равенстве нижнему условию в третьей строчке...

Метод по началу мне показался интересным, но судя по твоему минусу ты даже не понял в чём суть - ребёночка то в мутной водичке ты выплеснул не глядя - заблуждайся дальше...
73. Сергей Старых (tormozit) 4523 03.08.17 09:23 Сейчас в теме
(72) Научиться признавать ошибки - непростая задача. Я помогу тебе.
Прикрепленные файлы:
тест.t1c
spetzpozh; mvxyz; teploukhov; sasha777666; unichkin; Sashares; +6 Ответить
74. Вячеслав (slawa) 24 11.08.17 14:07 Сейчас в теме
А так сдвинуть лидирующий Истина или Ложь
Тоже вроде ничего и в глаза не бросается

	Если									Ложь
		ИЛИ СС_ТемаЗадание.СоздатьСчетНаОплату
		ИЛИ СС_ТемаЗадание.СоздатьКП
		ИЛИ СС_ТемаЗадание.СоздатьДоговор
	Тогда
	....
76. Alex Kles (KlesAlex) 4 28.08.17 17:03 Сейчас в теме
С таким количеством скобок и сравнений не часто сталкиваюсь.
Но из похожего - различные заполнения свойств через равенство оформляю по принципу чтобы знак равенства был в одном месте.
Например

НоваяЗапись_____ =_____ПеременнаяТаблицы.Добавить();
НоваяЗапись.а1___=_____ПолучитьА1();
НоваяЗапись.Упр__=_____ПолучитьУпр();
78. Сергей Старых (tormozit) 4523 28.08.17 20:45 Сейчас в теме
(76) Такое оформление кода я лично не использую и считаю его больше вредным чем полезным, т.к. редактированию оно сильно мешает. А вот читать такой код конечно приятнее. В идеале конечно хочется 2 режима просмотра кода - для чтения и для редактирования - с быстрым переключением между ними. Тогда такое оформление будет приносить больше пользы чем вреда.
77. Сан Саныч (herfis) 212 28.08.17 18:04 Сейчас в теме
1) Выносить "Тогда" на отдельную строку в сложных условиях мне тоже казалось нагляднее и удобнее.
Но плюнул в итоге, т.к. противоречит стайл-гайдам 1С и автоформатирование конфигуратора тоже его не любит (корежит при рефакторинге)
2) заменять первое условие на Истина/Ложь для удобства рефакторинга тоже неоднозначный вариант. Тасовать при рефакторинге чуть удобнее и быстрее, но опять-таки больше авторский стиль получается. А я стараюсь писать так, чтобы левому человеку код глаз не резал. И ценю такой же чужой код.
А в сухом остатке получается просто грамотное составление логических выражений и оформление их по одинэсовскому стайл-гайду.
rpgshnik; +1 Ответить
79. Uladzimir - (nvv1970) 31.08.17 07:42 Сейчас в теме
За собой и за другими замечал в своё время - у новичков есть желание усложнить условия, объединить их в одно, написать их сложно. Это как бы показывает уровень.
Более опытные стараются дробить на отдельные конструкции, чтобы при отладке понимание причин того или иного результата условия не занимало больше 0 секунд. Есть 10 составляющих условия - в идеале столько же веток выполнения.
На практике конечно нужна золотая середина. Но мой посыл: УПРОЩЕНИЕ - наше все, но без фанатизма.
Пс: от паразитных ложь и истина однозначно коробит.
vlad.frost; +1 Ответить
80. Владислав Мороз (vlad.frost) 172 31.08.17 12:10 Сейчас в теме
81. Сергей Старых (tormozit) 4523 31.08.17 13:58 Сейчас в теме
(80) Тоже просто процитирую это здесь
Объединение условных операторов
Проблема: У вас есть несколько условных операторов, ведущих к одинаковому результату или действию.
Решение: Объедините все условия в одном условном операторе.
82. Сергей Старых (tormozit) 4523 03.09.17 16:43 Сейчас в теме
Добавил в статью по одному плюсу и минусу

+ сокращает левые отступы, вложенность условий, количество строк в коде по сравнению с другими удобочитаемыми стилями
- автоформатирование кода выравнивает все строки условия по одной границе
85. Дмитрий Касминюк (Vortigaunt) 11 20.09.17 14:26 Сейчас в теме
Cам пришел к чему-то аналогичному.
Сначала длиннные условия у меня перестали влезать в одну строку на мониторе, поэтому разбил их переносами.
Плюс при сравнении / объединении сразу видно в какой части условия изменение.
А потом до меня дошло, что скобочки в сложных условиях это почти то же самое, что и фигурные скобки, например, в java. И если написание кода в 1 строчку - это плохо и рекомендуется форматировать код оступами, то почему нельзя также форматировать сложные вложенные условия?
89. Александр Никитин (ManyakRus) 271 09.11.17 15:27 Сейчас в теме
вместо Истина надо писать 1=1
Ложь: 0=1
Я во всех запросах пишу:
ГДЕ 1=1
:)
90. Виталий Чебан (VitaliyCeban) 298 09.11.17 16:25 Сейчас в теме
Не в огорчение сказано, но на ум приходят только три слова: "адъ и израиль". Бедные мои глаза.

Код из шапки я бы написал следующим образом:
Если НомерИзменяемойКолонки = "4" 
 ИЛИ НомерИзменяемойКолонки = "5"
 ИЛИ НомерИзменяемойКолонки = "7" 
 ИЛИ НомерИзменяемойКолонки = "8" И ГруппаРасчета = мИдГруппы7 Тогда
    Расчет(ГруппаРасчета);
КонецЕсли;


Минусы по сравнению с подходом автора: Нужно вручную выравнивать пробелами.
Плюсы: Отличная читаемость.

По аналогии с индексами в СУБД: наличие индекса увеличивает время записи, но последующие чтения выполняются существенно быстрее. Так и тут, лучше один раз "дольше" написать, но потом чтобы не было больно глазам и стыдно за свой код.
91. Анатолий Ситников (acsent) 1042 09.11.17 18:48 Сейчас в теме
нужно бы и скобочку последнюю переносить
Если Ложь
    Или НомерИзменяемойКолонки = "4"
    Или НомерИзменяемойКолонки = "5"
    Или НомерИзменяемойКолонки = "7"
    Или ( Истина
        И НомерИзменяемойКолонки = "8"
        И ГруппаРасчета = мИдГруппы7
    ) // Эту скобочку тоже переносим если нужно будет закомментировать
Тогда
Показать
92. Сергей Старых (tormozit) 4523 10.11.17 00:06 Сейчас в теме
(91) Пробовал так, но получается слишком много почти пустых строк (по количеству закрывающих скобок). Тут минусы для меня перевесили плюсы. Однако когда возникает потребность закомментировать последнее условие группы, я делаю именно так, но временно.
96. Анатолий Ситников (acsent) 1042 10.11.17 18:10 Сейчас в теме
(92) Те первую истину писать не влом, а вот 2ю скобочку переносить влом.
А можно ведь и вторую истину писать ))

ИЛИ (ИСТИНА
И НомерИзменяемойКолонки = "8"
И ГруппаРасчета = мИдГруппы7
И ИСТИНА)
97. Сергей Старых (tormozit) 4523 10.11.17 19:33 Сейчас в теме
(96) Где я писал что мне "в лом"? Я писал "слишком много почти пустых строк".
93. Дмитрий Котов (rpgshnik) 128 10.11.17 05:24 Сейчас в теме
(91)
	Если ЛОЖЬ 
		ИЛИ НомерИзменяемойКолонки = "4" 
		ИЛИ НомерИзменяемойКолонки = "5"		
		ИЛИ НомерИзменяемойКолонки = "7" 
		ИЛИ (ИСТИНА
		И НомерИзменяемойКолонки = "8" 
		И ГруппаРасчета = мИдГруппы7)  //нормально комментируется
		Тогда	
		Расчет(ГруппаРасчета);
	КонецЕсли;
Показать
94. Дмитрий Котов (rpgshnik) 128 10.11.17 05:26 Сейчас в теме
В результате форматирования будет выглядить всё так:

	Если ЛОЖЬ 
		ИЛИ НомерИзменяемойКолонки = "4" 
		ИЛИ НомерИзменяемойКолонки = "5"		
		ИЛИ НомерИзменяемойКолонки = "7" 
		ИЛИ (ИСТИНА
		И НомерИзменяемойКолонки = "8" 
		И ГруппаРасчета = мИдГруппы7)
		Тогда	
		Расчет(ГруппаРасчета);
	КонецЕсли;
Показать


Неоднозначный подход конечно, вроде бы интересно, но в то же время смущают эти ЛОЖЬ ИЛИ и ИСТИНА И, возможно попробую методику. Но в начальном примере реально было жутко много скобок, которые можно было просто убрать и облегчить читабельность)))
95. Анатолий Ситников (acsent) 1042 10.11.17 18:07 Сейчас в теме
Вообще первичное удаление скобочек называется: приведение к дизъюнктивной нормальной форме
98. IntelInside (G) (IntelInside) 126 13.11.17 19:50 Сейчас в теме
Сложные и многоэтажные логические конструкции сложны для понимания. Это зло профессии и не нужно их дополнительно усложнять. Их надо нещадно рефакторить и сводить к простым. Правдо это долго.
Фактически Вы сводите логическую конструкцию к легко читаемому виду, где в начале каждой строки стоит условие.
Для И получается легко читаемое на одном дыхании ЕСЛИ ИСТИНА-И-Условие_а-И-Условие_б. Но для ИЛИ получается ересь читаемая как ЕСЛИ ЛОЖЬ-ИЛИ-Условие_а-ИЛИ-Условие_б.
По моему, если условие не очень многоэтажное, то оно и так может читаться при хорошем форматировании. А если условие строк эдак на 15-20, то его Ваша форма только дополнительно усложнит. Его надо рефакторить.

ПС. Спасибо за мысль. а) буду делать дополнительные оптимизации к своему компилятору. б) при расширении грамматики подумаю над возможностью опустить первый операнд И\ИЛИ: ЕСЛИ И Условие_а И Условие_б; ЕСЛИ ИЛИ Условие_а ИЛИ Условие_б.

ППС. Можно завести себе для красоты константы или пока функции:

(Фантазии, перспектива)
Конст ИстинаЛюбое = Ложь ЭКСПОРТ
Конст ИстинаКаждое = Истина ЭКСПОРТ
---
ЕСЛИ ИстинаЛюбое
ИЛИ Условие_а
ИЛИ Условие_б

ЕСЛИ ИстинаКаждое
И Условие_а
И Условие_б
99. Сергей Старых (tormozit) 4523 15.11.17 10:37 Сейчас в теме
Результаты опроса http://www.forum.mista.ru/topic.php?id=807921 показали, что соотношение программистов, которые сразу понимают, которые понимают более чем через 10 секунд, которые не понимают, корректировано составляет
4:1:1
С учетом того, что после нескольких прочтений, вторая категория научится машинально это читать, получается соотношение понимающие:непонимающие
5:1 или 84:16%.
100. Решитко Дмитрий (grumagargler) 327 15.11.17 18:04 Сейчас в теме
(99) посмотрел опрос, посмортел тему, не увидел связи.
Стоило бы добавить в опрос тех, кто считает наличие указанных конструкций неприемлемым в конструкции Если. Интересно было бы посмотреть соотношение.
корректировано составляет

как вы считали соотношение 4:1:1?
Оставьте свое сообщение