Документ на документ. Автоматическое создание связанных документов

Публикация № 1122686

Разработка - Практика программирования

авто создание документов на основании практика программирование

Пример решения простой и распространенной задачи - автоматическое создание документа на основании другого документа.

Предисловие

Вы любите свое дело? Я да! Десятки, сотни или может даже тысячи (трудно уже подсчитать) решенных задач. Огромное количество человеко-часов потрачено. С опытом начинаешь использовать некоторые решения в качестве шаблонов, даже если считаешь их костылями. Просто приходится.

В одной из прошлых статей "Три костыля. Сказ про фокусы в коде" мы уже касались этой темы. Практически все понимают, что решенная в адекватные сроки задача приносит куда больше успеха, чем идеальное решение за границей дедлайна.

Именно о таком решении, которое может создавать сомнения в постановке задачи и качестве ее решения, мы сегодня и поговорим. А именно - об автоматическом создании документа на основании другого документа. На практике она не редкость.

Постановка задачи

Решим практическую задачу. Необходимо при проведении документа "Перемещение товаров" для ордерных складов автоматически создавать на основании документ "Расходный ордер на товары". При последующих изменения документа перемещения нужно изменять и расходный ордер. Доработка выполняется на конфигурации "Управление производственным предприятием" редакции 1.3.

Да, я конечно же понимаю, что это устаревшая конфигурация и так далее. Но вся информация в статье актуальна и для современных конфигураций, а продемонстрированный ниже код может быть использован Вами с необходимыми модификациями.

Это не идеальное решение. Вообще, автоматическое синхронное создание документов на основании документа при проведении / записи / другом событии - это сомнительное решение в любом случае. К этому мы еще вернемся.

Общий принцип

Изменение связанных документов от записываемого / проводимого документа-основания лучше всего выполнять в обработчике "ПриЗаписи", чтобы не влиять на процедуру проведения документа. Рекомендация действительна только в тех случаях, когда это позволяет логика прикладного решения или поставленной задачи. 

На следующем листинге показан пример обработчика изменения связанного документа:

// Источник - объект документа источника, на основании которого
// должны автоматически создаваться другие документы
// СвязанныйДокумент - объект документа, создаваемого автоматически
//
// Перед выполнением дальнейшего алгоритма выполняется поиск связанного 
// документа. Если документ не найден, то создается новый
//
Если Источник.Проведен Тогда   
	// Если источник проведен, то зависимый документ перезаполняется
	// на основании источника и проводится 
	СвязанныйДокумент.ПометкаУдаления = Ложь;                 
	ОбновитьЗависимыйДокумент(СвязанныйДокумент, Источник);
	СвязанныйДокумент.Записать(РежимЗаписиДокумента.Проведение);   	 
ИначеЕсли Источник.ПометкаУдаления Тогда 	
	// Если источник помечен на удаление, то связанный документ также
	// помечается на удаление. Если он был проведен, то процедура
	// "УстановитьПометкуУдаления" инициирует отмену проведения документа
	Если НЕ СвязанныйДокумент.ЭтоНовый() Тогда
		// Если связанный документ еще не записан в базу, то
		// никакие действия не выполняются
		СвязанныйДокумент.УстановитьПометкуУдаления(Истина);	
	КонецЕсли;
Иначе // Выполняется запись документа без проведения или установки
	  // пометки удаления 
	Если СвязанныйДокумент.ЭтоНовый() Тогда
		// Если связанный документ не записан в базу, то заполняем его и
		// выполняем запись документа без проведения
		ОбновитьЗависимыйДокумент(СвязанныйДокумент, Источник);
		СвязанныйДокумент.Записать(РежимЗаписиДокумента.Запись);	
	ИначеЕсли СвязанныйДокумент.Проведен Тогда
		// Если связанный документ был проведен, то выполняем отмену проведения
		СвязанныйДокумент.Записать(РежимЗаписиДокумента.ОтменаПроведения);	
	Иначе
		// В остальных случаях просто записываем зависимый документ
		// Если была установлена пометка удаления - снимаем ее
		СвязанныйДокумент.ПометкаУдаления = Ложь;
		СвязанныйДокумент.Записать(РежимЗаписиДокумента.Запись);	
	КонецЕсли;
КонецЕсли

Комментарии достаточно подробны. Рассмотрим работу алгоритма на практической задаче, которая была озвучена выше.

Реализация

В типовой конфигурации "Управление производственным предприятием" для автосоздания документа расходного ордера товаров создадим подписку на событие "ПриЗаписиДокументаПеремещения" на событие "ПриЗаписи" со следующим обработчиком:

Процедура ПриЗаписиДокументаПеремещенияПриЗаписи(Источник, Отказ) Экспорт
	
	// Находим подчиненный документ "Расходный ордер на товары"
	Запрос = Новый Запрос;
	Запрос.Текст = 	"ВЫБРАТЬ
	|	РасходныйОрдерНаТовары.Ссылка
	|ИЗ
	|	Документ.РасходныйОрдерНаТовары КАК РасходныйОрдерНаТовары
	|ГДЕ
	|	РасходныйОрдерНаТовары.ДокументПередачи = &ДокументПередачи
	|	И РасходныйОрдерНаТовары.ВидОперации = 
	|		ЗНАЧЕНИЕ(Перечисление.ВидыОперацийРасходныйОрдер.Перемещение)"; 				
	Запрос.УстановитьПараметр("ДокументПередачи", Источник.Ссылка);			  
	Выборка = Запрос.Выполнить().Выбрать();
	
	Если Источник.ВидОперации = Перечисления.ВидыОперацийПеремещениеТоваров.ТоварыПродукцияПоОрдерам Тогда	
		Если Выборка.Следующий() Тогда 		
			СвязанныйДокумент = Выборка.Ссылка.ПолучитьОбъект();  		
		Иначе     		
			СвязанныйДокумент      = Документы.РасходныйОрдерНаТовары.СоздатьДокумент();
			СвязанныйДокумент.Дата = Источник.Дата+1;
			ОбновитьНумерациюОбъектов(Метаданные.Документы.РасходныйОрдерНаТовары);
			СвязанныйДокумент.УстановитьНовыйНомер(); 				
		КонецЕсли;   	
		
		// должны автоматически создаваться другие документы
		// СвязанныйДокумент - объект документа, создаваемого автоматически
		//
		// Перед выполнением дальнейшего алгоритма выполняется поиск связанного 
		// документа. Если документ не найден, то создается новый
		//
		Если Источник.Проведен Тогда   
			// Если источник проведен, то зависимый документ перезаполняется
			// на основании источника и проводится 
			СвязанныйДокумент.ПометкаУдаления = Ложь;                 
			ОбновитьРасходныйОрдер(СвязанныйДокумент, Источник);
			СвязанныйДокумент.Записать(РежимЗаписиДокумента.Проведение);   	 
		ИначеЕсли Источник.ПометкаУдаления Тогда 	
			// Если источник помечен на удаление, то связанный документ также
			// помечается на удаление. Если он был проведен, то процедура
			// "УстановитьПометкуУдаления" инициирует отмену проведения документа
			Если НЕ СвязанныйДокумент.ЭтоНовый() Тогда
				// Если связанный документ еще не записан в базу, то
				// никакие действия не выполняются
				СвязанныйДокумент.УстановитьПометкуУдаления(Истина);	
			КонецЕсли;
		Иначе // Выполняется запись документа без проведения или установки
			// пометки удаления 
			Если СвязанныйДокумент.ЭтоНовый() Тогда
				// Если связанный документ не записан в базу, то заполняем его и
				// выполняем запись документа без проведения
				ОбновитьРасходныйОрдер(СвязанныйДокумент, Источник);
				СвязанныйДокумент.Записать(РежимЗаписиДокумента.Запись);	
			ИначеЕсли СвязанныйДокумент.Проведен Тогда
				// Если связанный документ был проведен, то выполняем отмену проведения
				СвязанныйДокумент.Записать(РежимЗаписиДокумента.ОтменаПроведения);	
			Иначе
				// В остальных случаях просто записываем зависимый документ
				// Если была установлена пометка удаления - снимаем ее
				СвязанныйДокумент.УстановитьПометкуУдаления(Ложь);	
			КонецЕсли;
		КонецЕсли
	Иначе
		// При смене вида операции "ТоварыПродукцияПоОрдерам" помечаем на удаление
		// зависимый документ расходного ордера
		Если Выборка.Следующий() Тогда 		
			СвязанныйДокумент = Выборка.Ссылка.ПолучитьОбъект();
			СвязанныйДокумент.ПометкаУдаления = Ложь;
			СвязанныйДокумент.Записать(РежимЗаписиДокумента.Запись);
		КонецЕсли;
	КонецЕсли;
	
КонецПроцедуры

Сама процедура заполнения зависимого расходного ордера очень проста:

Процедура ОбновитьРасходныйОрдер(ДокументРасхода, Источник)
	
	// Заполняем одноименные реквизиты расходной накладной
	// из документа перемещения
	ЗаполнитьЗначенияСвойств(ДокументРасхода, Источник, , "Номер");
	// Дату расходного ордера увеличиваем на 1 секунду 
	// от даты документа перемещения
	ДокументРасхода.Дата = Источник.Дата + 1;
	ДокументРасхода.ВидОперации = Перечисления.ВидыОперацийРасходныйОрдер.Перемещение;
	ДокументРасхода.ДокументПередачи = Источник.Ссылка;
	// Заполняем таб. часть "Товары" из документа перемещения
	ДокументРасхода.Товары.Очистить();
	Для Каждого Стр Из Источник.Товары Цикл
		СтрокаТовары = ДокументРасхода.Товары.Добавить(); 
		ЗаполнитьЗначенияСвойств(СтрокаТовары,Стр);
	КонецЦикла;	
	
КонецПроцедуры

Представленное решение не является универсальным и служит лишь небольшим примером. Такие ситуации, когда существует несколько зависимых документов, не обрабатываются.

На скриншоте выше результат проделанной работы.

В типовых конфигурациях

Подобные решения встречаются не только в доработанных конфигурациях, но и в типовых решения как от фирмы "1С", так и в отраслевых конфигурациях от ее партнеров.

Возьмем самую популярную из них - "Бухгалтерия предприятия 3.0" (КОРП или нет - не важно). Практическим всем знаком документ "Реализация товаров и услуг" и документ на ее основании - "Счет-фактура выданный". Так вот, при проведении реализации товаров происходит актуализация данных в счет-фактуре.

Как это происходит? В обработчике реализации "ОбработкаПроведения" в сааамом конце процедуры есть такая строчка.

УчетНДСПереопределяемый.УстановитьСостояниеСчетаФактуры(ПараметрыДействия, Отказ, НЕ УстановленСтатусДокумента);

Мы не будем рассматривать что, куда и зачем передается, лишь общий принцип. В этой процедуре выполняются общие действия для счет-фактур при проведении или отмене проведения.

// Выполняет общие для всех документов действия связанные с проведением или отменой проведения счета-фактуры.
// При отсутствии явного указания счета-фактуры выполняется её поиск по документу-основанию.
//
// Параметры:
//  ПараметрыДействия - Структура - см. НовыеПараметрыСостоянияСчетаФактуры().
//  ОбновлятьСтатусСчетаФактурыПоДокументу - признак того, что по документу-основанию не установлен статус счета-фактуры, 
//                                           следовательно статус счета-фактуры должен установить сам счет-фактура.
//  Отказ        - Булево - в случае ошибки получает значение Истина при выполнении процедуры.
//
Процедура УстановитьСостояниеСчетаФактуры(ПараметрыДействия, Отказ = Ложь, ОбновлятьСтатусСчетаФактурыПоДокументу = Истина) Экспорт
// ...

В зависимости от типа изменения (изменена пометка удаления или флаг "Проведен") алгоритм актуализирует данные документа и записывает ее с соответствующим режимом записи (проведение, запись или отмена проведения).

Конечно, даже по сравнению с примером выше из УПП 1.3, это выглядит не так "страшно" и особо не должно влиять на качество работы информационной системы, но не всегда. Все-таки счет-фактура формирует движения, имеет различную логику при проведении или отмене проведения. Все это может занимать некоторое время, что увеличит длину транзакции основного документа реализации при проведении. Хорошо это или плохо - зависит от конкретной ситуации.

Это норма?

Вообще, с подобными решениями сталкивался довольно часто. Самая простая ситуация - нужно избавить пользователей от ручного ввода зависимых документов (расходных ордеров, счет-фактур, документов поступления или реализации и т.д.). Да, это может ломать логику типовых конфигураций, создавать проблемы производительности и сопровождения. Но все это неважно!

 
 Почему это может привести к проблемам с производительностью и можно ли этого избежать

Почему? Да потому что это приносит почти мгновенный эффект! "Запилил" днем, обновил вечером, а завтра все уже радуются, что у них больше времени на кофе и совещания :).

Обратная сторона - это увеличение технического долга, снижение пропускной способности системы в многопользовательской среде, усложнение разработки и тестирования. Но если бизнесу это не важно, то зачем "платить больше"?

Заключение

Выше продемонстрирован пример создания обработчика по синхронизации изменений основного и связанного документов. Пример можно использовать в большинстве задач, однако в сложных ситуациях такой подход вообще может быть не применим. Например, если критична производительность в многопользовательской среде, лучшим вариантом может стать доработка алгоритмов проведения документа по регистрам, чем создание таким способом зависимых документов.

Плюс ко всему, это может усложнить доработку решения, ведь никогда не знаешь, что таится за алгоритмом записи / проведения в подписках. Одно изменение по задаче - 2 часа сломанной конфигурации и простой бизнеса.

Имеет ли такой подход при разработке? Имеет, т.к. он может быть куда эффективней, чем "перепиливание" внутренностей процедур проведения или каких-либо регламентных алгоритмов в общих модулях.

А как такие задачи решаете Вы? Есть чем поделиться - добро пожаловать в комментарии!

Другие ссылки

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо
1. vdscom 19 16.09.19 10:08 Сейчас в теме
Добрый день.

я тоже иногда так поступаю. и не считаю это костылем.

в приведенном вами примере: использование цепочки взаимосвязанных документов лучше и с точки зрения разделения функционала, и с точки зрения дальнейших доработок/обновлений конфигурации, чем дублировать логику подчиненного документа в документе-основании

хотя, согласен, могут быть и ситуации, где такой подход неприемлем
2. laperuz 42 16.09.19 13:09 Сейчас в теме
Сейчас в УТ 11 такое с онлайн-взаиморасчетами, только хуже. Там не 1 к 1 документы, а много ко многим. Ох и хватанули мы с этим..
17. Brawler 458 18.09.19 12:00 Сейчас в теме
(2) С этого момента бы поподробнее узнать, что там за грабли ибо ERP поджимает новыми релизами и скоро тоже придется включать онлайн взаиморасчеты.
21. laperuz 42 19.09.19 09:24 Сейчас в теме
(17)
Сейчас для онлайн-взаиморасчетов схема такая:
При проведении любого документа, связанного с взаиморасчетами, сам документ делает движение по регистру Расчеты с клиентами(с поставщиками). В модуле набора записей отписан запрос который вычисляет изменение регистра и по изменению формируются движения по регистру расчеты с клиентами(поставщиками) по срокам. При этом регистратором по второму регистру является не сам документ, а служебный документ "Регистратор расчетов". На версии 11.4.7 было сопоставление 1 регистратор расчетов на 1 ключ аналитики учета по партнерам. Получалось, что при любом проведении документа перезаписывались движения вообще за весь период ведения учета в базе по этому контрагенту. Естественно время проведения только росло. В 11.4.8 переписали, теперь регистратор расчетов создается новый, как только в старом по данному ключу аналитики количество записей в регистре превышает 1000. Стало получше, но все равно - проводим 1 документ, а перезаписывается набор с 1000 записей. Кроме того, внутри процедуры все очень неоптимально, например есть соединение с виртуальными таблицами. В итоге после того, как я переписал запрос, он стал вместо 29 секунд выполняться 0.5:) Ну и еще у нас есть проблемы с РИБ в этой схеме - периодически расходятся регистр, в котором регистратор сам документ и регистр, в котором регистратор служебный документ.
mivari; acanta; +2 Ответить
22. Brawler 458 19.09.19 12:25 Сейчас в теме
(21) Рука лицо...
По поводу производительности и как оптимизировать можно в 1С писали?
3. recon 35 16.09.19 13:26 Сейчас в теме
Лучше для таких целей использовать регистр сведений с регистратором куда писать информацию по документу, требующему создания на основе себя других документов. Потом регламентно запускать обработку и создавать документы отражения по записям в РС.

Из плюсов такого подхода
- гибкость механизма - в любой момент без существенного изменения кода можно менять алгоритм создания документов, например подключать не типовые документы (добавленные разработчиком), создавать документы другого типа.
- Все процедуры контроля при проведении документа - источника отрабатывают и мы не получаем документы созданные по ошибочным документам (в процедуре при записи мы не получим отказ если не удалось провести документ и "уронем" всю транзакцию создания документа)
- Время транзакции при проведении документа не меняется
- Нет ошибок "В данной транзакции уже происходили ошибки" в случае ошибки создания документа отражения
- Проще контролировать события удаления, отмены проведения и других действий с документом источником, т.к. все данные по документам отражения собраны в одном регистре
- Проще ставить запрет на изменение документов созданных на основании другого документа, чтобы не получать рассогласованность данных

Из минусов
- Необходим отчет для мониторинга создания документов отражения. И человек который следит в случае если что то пошло не так.
- Необходимо в документе менять алгоритмы проверки реквизитов чтобы данных хватило на заполнение документа на основании источника
Andle; spec8s; +2 Ответить
4. Romarius 14 16.09.19 13:38 Сейчас в теме
В Обработчике "ПриЗаписи" мы не знаем результат, проведется ли документ. И нагружаем систему созданием документа, а потом удалением. Поэтому правильней делать в обработчике проведения.
itriot11; Andle; +2 Ответить
5. script 214 16.09.19 14:15 Сейчас в теме
Я вообще отношу такие задачи к категории "самый крайней случай".
Потому что документ - это чья-то персональная ответственность. А если ее нет, тогда это не документ, а может быть запись в каком ни-ть регистре сведений. И записать эту запись можно при проведении основного документа, а не документа-основания.

А если все таки это документ и чья-то ответственность, тогда и задача по вводу этого документа тоже чья-то ответственность. В этом случае создавать нужно задачу для того, кто должен этот документ ввести. А получатель должен эту задачу отработать.

Все остальное считаю костылями и иногда очень опасными.
6. vdscom 19 16.09.19 14:27 Сейчас в теме
(5) Потому что документ - это чья-то персональная ответственность.

в данном примере и документ Перемещение, и документ РасходныйОрдер - вполне могут быть персональной ответственностью одного конкретного сотрудника, и ВСЕГДА должны и создаваться, и модифицироваться синхронно. зачем тогда разбивать цепочку их создания на 2 отдельных процесса ?

то есть - применимость этого метода полностью зависит от конкретных условий поставленной задачи
9. itriot11 75 16.09.19 15:22 Сейчас в теме
(5) так следовать вашей логике, то и автоматические обмены данными следует избегать, поскольку за их ввод ответственность делится между пользователем и разработчиком обмена.
На самом деле наша задача качественно транспортировать данные, где не особо важно откуда и куда: База -> База, Документ -> Документ или Документ -> Регистр.
user774630; +1 Ответить
7. script 214 16.09.19 14:31 Сейчас в теме
Совершенно верно. Именно с этой точки зрения, в подобных документах фирма 1С сделала функцию - "Сформировать документы", которая открывать форму, в которой пользователь осознано выполняет создание подчиненных документов.
8. vdscom 19 16.09.19 14:40 Сейчас в теме
(7)

я реализовывал документ КомплектДокументов, который сам не делал никаких движений, но являлся рамочным документом (документом-основанием) для произвольного количества обычных документов. взаимосвязи между подчиненными документами настраивались визуально, и сохранялись в справочнике настроек. на инфостарте было несколько подобных разработок

суть такого пакетного создания комплекта документов - реализовать сложный функционал "виртуального" документа путем разложения его в базисе обычных, "атомарных" документов. в данном случае как раз и применима логика примера, описанного автором этой статьи
10. HardBall 16.09.19 17:58 Сейчас в теме
А если Попытка...Исключение ???
11. insurgut 187 16.09.19 23:13 Сейчас в теме
Если речь об обычных формах, то:
_ПодпискаНаСобытие
+
_ОбщийМодульДоработок
=
Простое обновление
12. sergey_garin 181 17.09.19 09:56 Сейчас в теме
Простите, но вот эти картинки на пол-экрана в стиле "модно-стильно-молодежно" немного мешают восприятию содержания. А простыню кода можно убрать подкат :)
13. YPermitin 7324 17.09.19 10:01 Сейчас в теме
14. Denic_01 28 17.09.19 11:06 Сейчас в теме
в ПриЗаписи что либо делать, особо не имеет смысла т.к. действительно не известен результат проведения, да и создаваемый документ как правило зависит от результата

Для себя выявил, что само правильно выполнять действия в событии ПослеЗаписи формы, на форме т.к. это в любом случае имеет смысл только при работе пользователя
в этом методе есть результат проведения, есть ссылка на объект и тп и вообще раз код дошел до этого места, значит прошли все проверки и есть смысл создать подчиненный объект.
15. GFC 18.09.19 09:48 Сейчас в теме
(14) Тоже считаю это одним из приемлемых вариантов и в плане производительгости, и в плане целостности данных, но есть одно НО... Ведь проведение документа может пользователь сделать и из списка, и групповой ТИПОВОЙ обработкой (при должных правах). А это в свою очередь приводило к тому, что простым смертным приходилось заррещать проведение из форм списка, форм выбора и бог знает еще откуда ))) Сколько задач - столько и оптимальных решений по шкале цена/качество
16. vdscom 19 18.09.19 11:37 Сейчас в теме
(15) зачем так сложно ? подписка на событие - наше все :)
разумеется, не при обработке события ПослеЗаписи формы...
19. Denic_01 28 18.09.19 14:30 Сейчас в теме
(15)
всё, да не всё - если кто реально заморачивался с этим на практике, тот в курсе, что возникает вагон нюансов с транзакциями и не записанными объектами
самый прикол ,это когда пользователь тыкает кнопку провести в не записанном документе да еще если документы зависят друг от друга т.е. главный не должен провестись, если подчиненный не провелся и наоборот, а еще в подчиненном, естественно, есть ссылка на главный, которая в транзакции пустая и установитьссылкунового, насколько помню, не поможет.
20. vdscom 19 18.09.19 17:38 Сейчас в теме
(19) приходилось заморачиваться :)

1. применялась следующая логика: все подчиненные документы имеют статус документа-основания (ПометкаУдаления,Проведен), время подчиненного документа на секунду больше предыдущего
2. УстановитьСсылкуНового - еще как помогает

да, все документы проводятся в одной транзакции. но, по этой логике, так и должно быть
18. Denic_01 28 18.09.19 14:24 Сейчас в теме
(14)
в форме списка всё можно отловить также и выполнить
групповой обработкой, как правило, клепать документы нет смысла - тут уж точно надо логику менять если такое возникло
23. elzetto 23.09.19 04:54 Сейчас в теме
Я все же на горячие клавиши завязал, что бы пользователь сам мог создавать автоматические документы с заполнением.
Оставьте свое сообщение

См. также

[СКД] Программное создание схемы компоновки данных

Статья Программист Стажер Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Сделаем отчет на СКД полностью программно, без использования макета "схема компоновки данных".

15.01.2020    7297    John_d    21       

Программы для исполнения 488-ФЗ: Маркировка товаров Промо

1 января 2019 года вступил в силу ФЗ от 25.12.2018 № 488-ФЗ о единой информационной системе маркировки товаров с использованием контрольных (идентификационных) знаков, который позволяет проследить движение товара от производителя до конечного потребителя. Инфостарт предлагает подборку программ, связанных с применением 488-ФЗ и маркировкой товаров.

Активный 2019 год на Инфостарт

Статья no Нет файла Бесплатно (free) О сообществе О жизни

О прошедшем 2019 годе в 100 и 500 словах.

26.12.2019    2228    YPermitin    24       

Подборка программ для взаимодействия с ЕГАИС Промо

ЕГАИС (Единая государственная автоматизированная информационная система) - автоматизированная система, предназначенная для государственного контроля за объёмом производства и оборота этилового спирта, алкогольной и спиртосодержащей продукции. Инфостарт рекомендует подборку проверенных решений для взаимодействия с системой.

Агрегатные функции СКД, о которых мало кто знает

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Пользуетесь ли Вы всеми возможными агрегатными функциями, которые предоставляет система компоновки данных? Если Вы используете только: СУММА, КОЛИЧЕСТВО, МИНИМУМ, МАКСИМУМ, СРЕДНЕЕ, то эта статья для Вас.

05.09.2019    23950    ids79    45       

Обмен данными. Консистентность vs Многопоточность

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Интеграция

Рассмотрим теоретические основы обмена данными. Какие бывают обмены, какие гарантии при этом даются, зачем идти на компромиссы и что при этом может пойти не так. Есть ли идеальная схема?

03.09.2019    6522    m-rv    1       

INFOSTART MEETUP Kazan. 13 марта 2020 г. Промо

Инфостарт продолжает путешествие по России. Следующая остановка - Казань. Тема мероприятия - управление и технологии автоматизации учета на платформе "1С: Предприятие". Ждем всех: докладчиков и участников! Стоимость участия - 5 500 рублей. Цена действительна до 30.01.2020

5 500

Функции СКД: ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Подробное описание и использование внутренних функций системы компоновки данных: Вычислить, ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив, ВычислитьВыражениеСГруппировкойТаблицаЗначений.

08.08.2019    33002    ids79    36       

Обработчики событий при записи объектов. Зачем и что за чем?

Статья Программист Нет файла v8 Бесплатно (free) Математика и алгоритмы

Программисту, имеющему немного опыта на платформе 1С 8.3, бывает сложно разобраться: ПередЗаписью, ПриЗаписи, ПослеЗаписи, на сервере, на клиенте, в модуле формы, в модуле объекта.... Эта шпаргалка была создана в процессе обучения и реального опыта с целью разложить всё по полочкам, чтобы было четкое понимание в каком случае какой обработчик нужно использовать и в какой последовательности они запускаются при записи и проведении документов. Данная статья будет полезна в большей степени начинающим разработчикам. Но и опытным позволит освежить информацию, упорядочить её.

25.07.2019    23596    4    AlbinaAAA    24       

Сдача регламентированной отчетности из программ 1С Промо

Сдача регламентированной отчетности из программ "1С" во все контролирующие органы без выгрузок и загрузок в другие программы. Для групп компаний действуют специальные предложения.

от 1500 руб.

Создание отчетов с помощью СКД - основные понятия и элементы

Статья Программист Нет файла v8 v8::СКД Бесплатно (free) Практика программирования Математика и алгоритмы

Основные принципы работы СКД. Понятия схемы компоновки и макета компоновки. Описание основных элементов схемы компоновки: наборы данных, поля, вычисляемые поля, ресурсы, параметры.

25.06.2019    31644    ids79    17       

Подсистема "Варианты отчетов". Используете ли Вы ее правильно?

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Работа с интерфейсом БСП (Библиотека стандартных подсистем)

Небольшая история про использование подсистемы "Варианты отчетов" из БСП. Используете ли Вы ее правильно?

04.06.2019    26032    YPermitin    51       

Базовый курс по обмену данными в системе 1С:Предприятие. Онлайн-интенсив с 12 по 28 мая 2020 г. Промо

Данный онлайн-курс предусматривает изучение механизмов платформы “1С:Предприятие”, обеспечивающих обмен данными между различными прикладными 1С-решениями и взаимодействие с другими информационными системами. Курс предназначен для тех, кто уже имеет определенные навыки конфигурирования и программирования в системе “1С:Предприятие”.

5500 рублей

Выгрузка документа по условию

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Разработка

Что делать, если документы нужно выгружать не все подряд, а по какому-то фильтру: статусу, дате, набору условий... А что если он соответствовал этим условиям, а потом перестал? А если потом опять начал? Такие ситуации заставили попотеть не одного программиста.

25.04.2019    9273    m-rv    2       

Как настроить правильную техподдержку (helpdesk, service desk на коленке)

Статья Программист Бизнес-аналитик Руководитель проекта Нет файла v8 УУ Управление взаимоотношениями с клиентами (СRM) Документооборот и делопроизводство Монитор заказов Учет рабочего времени Бесплатно (free) Управление услугами и сервисом

Эта статья будет полезна для компаний, которые оказывают техническую поддержку своим пользователям - внешним или внутренним клиентам. В статье я расскажу, как оказываем поддержку мы, как выстроили этот бизнес-процесс, что контролируем и на что обращаем внимание в работе. Вы можете использовать наш опыт при построении собственной системы поддержки или обратиться к нам за помощью за построением такой системы, будем рады помочь. В статье формируется основной набор правил, которые мы сформировали при настройке системы для себя, а так же небольшие примеры того, как мы эти правила применяем.

24.04.2019    11530    siddy    0       

1C:Предприятие для программистов: Запросы и отчеты. Второй поток. Онлайн-интенсив с 17 марта по 16 апреля 2020 г. Промо

Данный онлайн-курс предусматривает углубленное изучение языка запросов и возможностей системы компоновки данных, которые понадобятся при разработке отчетов, работающих на платформе “1С:Предприятие” в рамках различных прикладных решений. Курс предназначен для тех, кто уже имеет определенные навыки конфигурирования и программирования в системе “1С:Предприятие”, а также для опытных пользователей различных прикладных решений, которые используют в своей работе отчеты разного назначения.

6500 рублей

Преобразование EXCEL в таблицу значений без COM и других извращений

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Загрузка и выгрузка в Excel

Получение таблицы значений из excel в 1С v8, без COM, внешних источников данных и т.д. EXCELВТаблицуЗначений() - За 10 строчек кода! Реализация протестирована на 1С 8.3.12.1714 (x64).

18.04.2019    18206    9    Eret1k    43       

Как прикрутить ГУИД к регистру сведений

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Перенос данных из 1C8 в 1C8 Разработка

... и немного теории обмена данными. В частности, разберем боль всех, кто пишет небанальные обмены данными: как набору записей регистра сведений назначить гуид и далее использовать его в обмене для идентификации этого набора.

16.04.2019    12399    m-rv    16       

Программы для исполнения 54-ФЗ Промо

С 01.02.2017 контрольно-кассовая техника должна отправлять электронные версии чеков оператору фискальных данных - правила установлены в 54-ФЗ ст.2 п.2. Инфостарт предлагает подборку программ, связанных с применением 54-ФЗ, ККТ и электронных чеков.

Копирование числовых ячеек из 1С в Excel

Статья Системный администратор Программист Нет файла v8 1cv8.cf Windows Бесплатно (free) Загрузка и выгрузка в Excel Администрирование данных 1С

Решение проблемы, когда значения скопированных ячеек из табличных документов 1С в Excel воспринимаются последним как текст, т.е. без дополнительного форматирования значений невозможно применить арифметические операции. Поводом для публикации послужило понимание того, что целое предприятие с более сотней активных пользователей уже на протяжении года мучилось с такой, казалось бы на первый взгляд, тривиальной проблемой. Варианты решения, предложенные специалистами helpdesk, обслуживающими данное предприятие, а так же многочисленные обсуждения на форумах, только подтвердили убеждение в необходимости описания способа, который позволил мне качественно и быстро справиться с ситуацией.

15.01.2019    15561    itriot11    21       

Готовые переносы данных из различных конфигураций 1C Промо

Рекомендуем готовые решения для переноса данных из различных конфигураций 1C. C техподдержкой от разработчиков и гарантией от Инфостарт.

Новый подход к обмену данными EnterpriseData

Статья Программист Нет файла v8 v8::УФ Россия Бесплатно (free) Практика программирования Обмен через XML

Хочу предложить Вашему вниманию цикл статей, посвященных обмену данными через универсальный формат (EnterpriseData или ED).

14.12.2018    29268    ids79    72       

Подборка решений для взаимодействия со ФГИС «Меркурий» Промо

С 1 июля 2019 года все компании, участвующие в обороте товаров животного происхождения, должны перейти на электронную ветеринарную сертификацию (ЭВС) через ФГИС «Меркурий». Инфостарт предлагает подборку программ, связанных с этим изменением.

Универсальные функции ЗУП 3.1 / ЗКГУ 3.1, которые помогут в разработке

Статья Программист Нет файла v8 v8::СПР ЗКГУ3.0 ЗУП3.x БУ Зарплата Управление персоналом (HRM) Бесплатно (free) Универсальные функции

В статье размещен список стандартных процедур и функций с примерами, которые могут помочь при разработке (доработке) конфигураций Зарплата и управление персоналом ред. 3.1 и Зарплата и кадры государственного учреждения 3.1. Иногда бывает довольно сложно правильно получить данные или долго, поэтому лучшим вариантом будет использование стандартных процедур. Буду очень признателен, если Вы поделитесь своим опытом и предложите свои варианты стандартных процедур которые помогают в работе. Или предложите, как дополнить имеющиеся процедуры.

14.11.2018    51571    GeterX    95       

Автоматические и управляемые блокировки применительно к типовым конфигурациям 1С

Статья Программист Нет файла v8 v8::blocking 1cv8.cf Бесплатно (free) Математика и алгоритмы Практика программирования

Основные принципы работы с режимами автоматических и управляемых блокировок в 1С Предприятие 8. Теория и применение в типовых конфигурациях: БП, УТ, ЕРП

10.11.2018    26291    ids79    40       

1C:Предприятие для программистов: Расчетные задачи (зарплата). Онлайн-интенсив с 01 по 17 июня 2020 г. Промо

Данный онлайн-курс предусматривает изучение механизмов платформы “1С:Предприятие”, которые предназначены для автоматизации периодических расчетов, а именно - для расчета зарплаты. Курс предназначен для тех, кто уже имеет определенные навыки конфигурирования и программирования в системе “1С:Предприятие”, а также для опытных пользователей прикладного решения “1С:Зарплата и управление персоналом” и прочих прикладных решений, в которых реализован функционал расчета зарплаты.

4900 рублей

Git + 1С. Часть 1. Как подключиться к команде разработки и начать использовать Git

Статья Системный администратор Программист Нет файла v8 1cv8.cf Бесплатно (free) Инструментарий разработчика Управление проектом

Первая статья из цикла инструкций по работе с Git в 1С-разработке. Рассмотрим, как настроить рабочее место, как получить свою "копию" проекта для разработки и приступить к полезным действиям. Все примеры будут изложены в рамках трёх практических кейсов: 1. Моя команда дорабатывает типовую конфигурацию, использует приватный репозиторий на BitBucket, в котором версионируются внешние отчеты/обработки, расширения конфигураций и правила обмена; 2. Я участвую в стартап-команде, которая разрабатывает свою конфигурацию с использованием Git и GitLab; 3. Я принимаю участие в развитии OpenSource-продукта на GitHub как заинтересованный разработчик (контрибьютор).

18.10.2018    47243    stas_ganiev    73       

Вспомогательные инструкции в коде 1С

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования

Помогаем редактору кода 1С помогать нам писать и анализировать код.

15.10.2018    23728    tormozit    100       

Голосование за доклады на INFOSTART MEETUP Kazan - до 25 февраля. Промо

Выбирайте и голосуйте за самые интересные доклады! Лучшие из лучших попадут в окончательную программу казанского митапа. Оставить свой голос можно до 25 февраля 2020 года.

Из Excel в 1С запросом

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Загрузка и выгрузка в Excel

... ну, конечно, не прям так типовым языком запросов, а расширенным языком запросов. Речь пойдет о том, как "залить" данные в таблицы 1С и не пилить при этом бесконечного количества наколеночных обработок.

14.08.2018    16459    m-rv    5       

Базовый курс по управлению ИТ-проектами. Курс проходит с 26 февраля по 22 апреля 2020 года. Промо

Отличительная черта курса - органичное сочетание трех вещей: 1.Теория проектного управления (PMI®+Agile Alliance+Российские ГОСТ+Методологии от 1С); 2. Опыт внедрения продуктов 1С (опыт франчайзи и успешных компаний + тренды Infostart Event и Agile Days); 3. Разбор реальных проблем и рекомендации экспертов по проектам слушателей. Мы будем фиксироваться на тех инструментах, которые реально оказываются полезными в практике руководителей проектов внедрения. Ведущая курса - Мария Темчина.

от 11000 рублей

Повышаем эффективность разработки правил обмена

Статья Программист Нет файла v8 КД ОС Бесплатно (free) Практика программирования Перенос данных из 1C8 в 1C8

Как повысить скорость и качество разработки правил обмена? Как вести групповую разработку правил обмена? Как облегчить сопровождение правил обмена после передачи в эксплуатацию? Об этом и многом другом вы можете узнать из этой статьи.

25.06.2018    23181    olegtymko    47       

Как сделать запрос на изменение данных

Статья Программист Нет файла v8 v8::Запросы 1cv8.cf Бесплатно (free) Практика программирования

В статье приведены особенности внутренней архитектуры и примеры работы с расширением языка запросов 1С.

01.06.2018    24611    m-rv    21